Membuat Saklar Online dengan NodeMCU esp8266 dan Relay 8Ch

Membuat Saklar Online sehingga bisa diakses dimana saja bahkan bisa dibuatkan jadwal jika anda punya Mikrotik dari schedulernya. Adapun bahan-bahan yang diperlukan adalah sebuah platform Iot open source berbiaya rendah NodeMCU ESP8266 dan Relay 8 Ch untuk arduino. Berhubung di Djatun Computer memang ada sebuah router Mikrotik yang online 24 jam dan terhubung ke internet dilengkapi baterai backup pula jadi sangat mendukung untuk membuat saklar online bisa diakses dari hape baik dengan aplikasi android maupun web browser. Ditambah dengan cloud VPS yg terinstall Linux Ubuntu menjadikan saklar ini bisa diakses dari mana saja dengan menginstall sstp server yg terhubung ke Mikrotik yg di rumah.

Setelah bahan disiapkan, install Arduino IDE, Driver ESP8266, menambahkan board di board manager Arduino IDE dengan cara pastekan URL http://arduino.esp8266.com/stable/package_esp8266com_index.json ke Additional Board Manager URLs dari menur File - Preferences, kemudian cari esp8266 di menu Tools - Board - Board Manager (pilih yang terbaru).

Pastekan Kode di bawah ini ke Arduino IDE dan compile, jangan lupa mengganti nama AP sesuai dengan SSID wifi yang ada disini wifi kita Djatun-HotSpot. Saya tambahkan juga SoftAP dengan nama DjC-IoT supaya nodemcu ini bisa diakses langsung, ini diperlukan apabila WiFi di rumah sedang mati.

/*********
  Rui Santos
  Complete project details at https://RandomNerdTutorials.com/esp8266-relay-module-ac-web-server/
  
  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
*********/

// Import required libraries
#include "ESP8266WiFi.h"
#include "ESPAsyncWebServer.h"

// Set to true to define Relay as Normally Open (NO)
#define RELAY_NO    true

// Set number of relays
#define NUM_RELAYS  8

// Assign each GPIO to a relay
int relayGPIOs[NUM_RELAYS] = {5, 4, 0, 2, 14, 12, 13, 15};
// Nama lampu berdasarkan GPIOnya
const char* relayNAMEs[NUM_RELAYS] = {"Teras Besar", "Teras Kecil", "Ruang Tamu 1", "Ruang Tamu 2", "Ruang Tamu 3", "Ruang Tamu 4", "Teras Belakang", "Dapur"};
// Replace with your network credentials
const char* ssid = "Djatun-HotSpot";
const char* password = "";

const char* PARAM_INPUT_1 = "relay";  
const char* PARAM_INPUT_2 = "state";

const char* ssidAP = "DjC-IoT"; // The name of the Wi-Fi network that will be created
const char* passwordAP = "Passwordnya";   // The password required to connect to it, leave blank for an open network

// Create AsyncWebServer object on port 80
AsyncWebServer server(80);

const char index_html[] PROGMEM = R"rawliteral(
<!DOCTYPE HTML><html>
<head>
  <meta name="viewport" content="width=device-width, initial-scale=1">
  <meta http-equiv="refresh" content="5">
  <style>
    html {font-family: Arial; display: inline-block; text-align: center;}
    h2 {font-size: 3.0rem; background-color:tomato;}
    p {font-size: 3.0rem;}
    body {max-width: 600px; margin:0px auto; padding-bottom: 25px; background-color:powderblue;}
    .switch {position: relative; display: inline-block; width: 120px; height: 68px} 
    .switch input {display: none}
    .slider {position: absolute; top: 0; left: 0; right: 0; bottom: 0; background-color: #ccc; border-radius: 34px}
    .slider:before {position: absolute; content: ""; height: 52px; width: 52px; left: 8px; bottom: 8px; background-color: #fff; -webkit-transition: .4s; transition: .4s; border-radius: 68px}
    input:checked+.slider {background-color: #2196F3}
    input:checked+.slider:before {-webkit-transform: translateX(52px); -ms-transform: translateX(52px); transform: translateX(52px)}
  </style>
</head>
<body>
  <h2>DjC-IoT</h2>
  %BUTTONPLACEHOLDER%
<script>function toggleCheckbox(element) {
  var xhr = new XMLHttpRequest();
  if(element.checked){ xhr.open("GET", "/update?relay="+element.id+"&state=1", true); }
  else { xhr.open("GET", "/update?relay="+element.id+"&state=0", true); }
  xhr.send();
}</script>
</body>
</html>
)rawliteral";

// Replaces placeholder with button section in your web page
String processor(const String& var){
  //Serial.println(var);
  if(var == "BUTTONPLACEHOLDER"){
    String buttons ="";
    for(int i=1; i<=NUM_RELAYS; i++){
      String relayStateValue = relayState(i);
      buttons+= "<h4>Lampu " + String(i) + "#GPIO-" + relayGPIOs[i-1] + " (" + relayNAMEs[i-1] + ")</h4><label class=\"switch\"><input type=\"checkbox\" onchange=\"toggleCheckbox(this)\" id=\"" + String(i) + "\" "+ relayStateValue +"><span class=\"slider\"></span></label>";
    }
    return buttons;
  }
  return String();
}

String relayState(int numRelay){
  if(RELAY_NO){
    if(digitalRead(relayGPIOs[numRelay-1])){
      return "";
    }
    else {
      return "checked";
    }
  }
  else {
    if(digitalRead(relayGPIOs[numRelay-1])){
      return "checked";
    }
    else {
      return "";
    }
  }
  return "";
}

void setup(){
  // Serial port for debugging purposes
  Serial.begin(115200);

// Set all relays to off when the program starts - if set to Normally Open (NO), the relay is off when you set the relay to HIGH
  for(int i=1; i<=NUM_RELAYS; i++){
    pinMode(relayGPIOs[i-1], OUTPUT);
    if(RELAY_NO){
      digitalWrite(relayGPIOs[i-1], HIGH);
    }
    else{
      digitalWrite(relayGPIOs[i-1], LOW);
    }
  }
  
  // Connect to Wi-Fi
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi..");
  }

// Print ESP8266 Local IP Address
  Serial.println(WiFi.localIP());

WiFi.softAP(ssidAP, passwordAP);             // Start the access point
  Serial.print("Access Point \"");
  Serial.print(ssidAP);
  Serial.println("\" started");
  
  // Route for root / web page
  server.on("/", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/html", index_html, processor);
  });

// Send a GET request to <ESP_IP>/update?relay=<inputMessage>&state=<inputMessage2>
  server.on("/update", HTTP_GET, [] (AsyncWebServerRequest *request) {
    String inputMessage;
    String inputParam;
    String inputMessage2;
    String inputParam2;
    // GET input1 value on <ESP_IP>/update?relay=<inputMessage>
    if (request->hasParam(PARAM_INPUT_1) & request->hasParam(PARAM_INPUT_2)) {
      inputMessage = request->getParam(PARAM_INPUT_1)->value();
      inputParam = PARAM_INPUT_1;
      inputMessage2 = request->getParam(PARAM_INPUT_2)->value();
      inputParam2 = PARAM_INPUT_2;
      if(RELAY_NO){
        Serial.print("NO ");
        digitalWrite(relayGPIOs[inputMessage.toInt()-1], !inputMessage2.toInt());
      }
      else{
        Serial.print("NC ");
        digitalWrite(relayGPIOs[inputMessage.toInt()-1], inputMessage2.toInt());
      }
    }
    else {
      inputMessage = "No message sent";
      inputParam = "none";
    }
    Serial.println(inputMessage + inputMessage2);
    request->send(200, "text/plain", "OK");
  });
  // Start server
  server.begin();
}
  
void loop() {

}

Gunakan GPIO sesuai dengan pin berikut

dikarenakan tidak semua GPIO dari NodeMCU bisa dipakai untuk relay.

Contoh Saklar yang telah dibuat

adapun gambar ini mencoba untuk membuat 12Ch relay ternyata ketika dicoba tidak berhasil. Sehingga kita merekomendasikan untuk membuat 8Ch saja. Bisa saja Nodemcu untuk mengontrol 64Ch relay dengan menambahkan I2C untuk tiap 8Ch.

Kebanyakan kita sudah mempunyai smart phone android, jika tidak punya komputer/mikrotik kita bisa membuat jadwal nyala mati melalui aplikasi Automate di android

Contoh scriptnya di Mikrotik :

/tool fetch url="http://192.168.**.**/update?relay=2&state=0" keep-result=no;

ganti sesuai IPnya, nomor relaynya dan juga state 0 adalah mati dan 1 adalah nyala.

Contoh perintah di bash script:

curl -s -X GET "http://djatun.com:****/update?relay=4&state=1"

Bila punya server di cloud bisa juga diforward routingnya/DMZ sampai ke ip nodemcunya

Blog Djatun

Membuat Saklar Online dengan NodeMCU esp8266 dan Relay 8Ch

Komentar

Catatan lain:

Install Desktop Environment di Armbian Server Aml s905x

Mining verus coins on various devices

Install WPS Office dan Brave Browser di Desktop Linux Armbian Arm64 tanpa menyita kapasitas emmc